Expose pluralization as an abolish.vim coercion

Author: tpope

doc/rails.txt

@@ -768,6 +768,14 @@ most terminals send <M-o> as <Esc>o anyways.
 One can also use the <C-E> surrounding in a plain Ruby file to append a bare
 "end" on the following line.
 
+						*rails-abolish*
+Among the many features of |abolish| on vim.org is the ability to change the
+inflection of the word under the cursor.  For example, one can hit crs to
+change from MixedCase to snake_case.  This plugin adds two additional
+inflections: crl for alternating between the singular and plural, and crt for
+altering between tableize and classify.  The latter is useful in changing
+constructs like BlogPost.all to current_user.blog_posts.all and vice versa.
+
 						*rails-cream*
 This plugin provides a few additional key bindings if it is running under
 Cream, the user friendly editor which uses Vim as a back-end.  Ctrl+Enter

plugin/rails.vim

@@ -143,6 +143,42 @@ augroup END
 
 command! -bar -bang -nargs=* -complete=dir Rails :if s:autoload()|call rails#new_app_command(<bang>0,<f-args>)|endif
 
+" }}}1
+" abolish.vim support {{{1
+
+function! s:function(name)
+    return function(substitute(a:name,'^s:',matchstr(expand('<sfile>'), '<SNR>\d\+_'),''))
+endfunction
+
+augroup railsPluginAbolish
+  autocmd!
+  autocmd VimEnter * call s:abolish_setup()
+augroup END
+
+function! s:abolish_setup()
+  if exists('g:Abolish') && has_key(g:Abolish,'Coercions')
+    if !has_key(g:Abolish.Coercions,'l')
+      let g:Abolish.Coercions.l = s:function('s:abolish_l')
+    endif
+    if !has_key(g:Abolish.Coercions,'t')
+      let g:Abolish.Coercions.t = s:function('s:abolish_t')
+    endif
+  endif
+endfunction
+
+function! s:abolish_l(word)
+  let singular = rails#singularize(a:word)
+  return a:word ==? singular ? rails#pluralize(a:word) : singular
+endfunction
+
+function! s:abolish_t(word)
+  if a:word =~# '\u'
+    return rails#pluralize(rails#underscore(a:word))
+  else
+    return rails#singularize(rails#camelize(a:word))
+  endif
+endfunction
+
 " }}}1
 " Menus {{{1