canvas-lms/app/coffeescripts/api/gradingPeriodSetsApi.coffee at stable · csseditor/canvas-lms · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
define [
  'jquery'
  'underscore'
  'i18n!grading_periods'
  'jsx/shared/helpers/dateHelper'
  'compiled/api/gradingPeriodsApi'
  'axios'
  'jsx/shared/CheatDepaginator'
  'jquery.instructure_misc_helpers'
], ($, _, I18n, DateHelper, gradingPeriodsApi, axios, Depaginate) ->
  listUrl = () =>
    ENV.GRADING_PERIOD_SETS_URL

  createUrl = () =>
    ENV.GRADING_PERIOD_SETS_URL

  updateUrl = (id) =>
    $.replaceTags(ENV.GRADING_PERIOD_SET_UPDATE_URL, 'id', id)

  serializeSet = (set) =>
    gradingPeriodSetAttrs =
      title: set.title
      weighted: set.weighted
      display_totals_for_all_grading_periods: set.displayTotalsForAllGradingPeriods
    grading_period_set: gradingPeriodSetAttrs
    enrollment_term_ids: set.enrollmentTermIDs

  baseDeserializeSet = (set) ->
    {
      id: set.id.toString()
      title: gradingPeriodSetTitle(set)
      weighted: !!set.weighted
      displayTotalsForAllGradingPeriods: set.display_totals_for_all_grading_periods
      gradingPeriods: gradingPeriodsApi.deserializePeriods(set.grading_periods)
      permissions: set.permissions
      createdAt: new Date(set.created_at)
    }

  gradingPeriodSetTitle = (set) ->
    if set.title?.trim()
      set.title.trim()
    else
      createdAt = DateHelper.formatDateForDisplay(new Date(set.created_at))
      I18n.t('Set created %{createdAt}', { createdAt })

  deserializeSet = (set) ->
    newSet = baseDeserializeSet(set)
    newSet.enrollmentTermIDs = set.enrollment_term_ids
    newSet

  deserializeSets = (setGroups) ->
    _.flatten _.map setGroups, (group) ->
      _.map group.grading_period_sets, (set) -> baseDeserializeSet(set)

  deserializeSet: deserializeSet

  list: () ->
    promise = new Promise (resolve, reject) =>
      Depaginate(listUrl())
        .then (response) ->
          resolve(deserializeSets(response))
        .fail (error) ->
          reject(error)
    promise

  create: (set) ->
    axios.post(createUrl(), serializeSet(set))
      .then (response) ->
        deserializeSet(response.data.grading_period_set)

  update: (set) ->
    axios.patch(updateUrl(set.id), serializeSet(set))
      .then (response) ->
        set