Error message when open .Rnw file

[xu-cheng]

The problem

When open any file with .Rnw as the suffix, neovim will show following error message for a short moment.

"test.Rnw" 5L, 62C
Error detected while processing /usr/local/Cellar/neovim/HEAD-4566f7c/share/nvim/runtime/indent/rnoweb
.vim:
line   13:
E475: Invalid argument: VimtexIndent(v:lnum)

FYI, .Rnw file basically is a combination of normal LaTeX file and R codes.

Step to produce

1. Create test.Rnw file with following content:

\documentclass{article}

\begin{document}
test
\end{document}

2. Create test.vim with following content:

set nocompatible
let &rtp  = '~/.config/nvim/plugged/vimtex,' . &rtp
let &rtp .= ',~/.config/nvim/plugged/vimtex/after'
filetype plugin indent on
syntax enable

3. Startup neovim by: nvim -u test.vim test.Rnw. You will see a flashed error message. In case of message disappearing too quickly, you can run :mess to view it.

Other Info

This is tested with the latest neovim running on macOS. If any other information is required, please let me know.

[xu-cheng]

I think the following patch can solve the problem.

diff --git a/indent/tex.vim b/indent/tex.vim
index 33dbf9b..0eccc41 100644
--- a/indent/tex.vim
+++ b/indent/tex.vim
@@ -16,33 +16,34 @@ let s:cpo_save = &cpoptions
 set cpoptions&vim
 
 setlocal autoindent
-setlocal indentexpr=VimtexIndent(v:lnum)
+setlocal indentexpr=VimtexIndent()
 setlocal indentkeys&
 setlocal indentkeys+=[,(,{,),},],\&,=item
 
-function! VimtexIndent(lnum) " {{{1
-  let l:prev_lnum = s:get_prev_line(prevnonblank(a:lnum - 1), 0)
-  if l:prev_lnum == 0 | return indent(a:lnum) | endif
+function! VimtexIndent() " {{{1
+  let l:lnum = v:lnum
+  let l:prev_lnum = s:get_prev_line(prevnonblank(l:lnum - 1), 0)
+  if l:prev_lnum == 0 | return indent(l:lnum) | endif
 
   " Get current and previous line and remove comments
-  let l:line = substitute(getline(a:lnum), '\\\@<!%.*', '', '')
+  let l:line = substitute(getline(l:lnum), '\\\@<!%.*', '', '')
   let l:prev_line = substitute(getline(l:prev_lnum),   '\\\@<!%.*', '', '')
 
   " Check for verbatim modes
-  if s:is_verbatim(l:line, a:lnum)
-    return empty(l:line) ? indent(l:prev_lnum) : indent(a:lnum)
+  if s:is_verbatim(l:line, l:lnum)
+    return empty(l:line) ? indent(l:prev_lnum) : indent(l:lnum)
   endif
 
   " Align on ampersands
   if get(g:, 'vimtex_indent_on_ampersands', 1)
         \ && l:line =~# '^\s*&'
         \ && l:prev_line =~# '\\\@<!&.*'
-    return indent(a:lnum) + match(l:prev_line, '\\\@<!&') - stridx(l:line, '&')
+    return indent(l:lnum) + match(l:prev_line, '\\\@<!&') - stridx(l:line, '&')
   endif
 
   " Use previous indentation for comments
   if l:line =~# '^\s*%'
-    return indent(a:lnum)
+    return indent(l:lnum)
   endif
 
   " Ensure previous line does not start with ampersand
@@ -54,7 +55,7 @@ function! VimtexIndent(lnum) " {{{1
   " Indent environments, delimiters, and tikz
   let l:ind = indent(l:prev_lnum)
   let l:ind += s:indent_envs(l:line, l:prev_line)
-  let l:ind += s:indent_delims(l:line, a:lnum, l:prev_line, l:prev_lnum)
+  let l:ind += s:indent_delims(l:line, l:lnum, l:prev_line, l:prev_lnum)
   let l:ind += s:indent_tikz(l:prev_lnum, l:prev_line)
   return l:ind
 endfunction

[lervag]

Agreed, however, I think optimally this should be solved by rnoweb.vim. They've made a false assumption on their side, because there is nothing wrong with how the VimtexIndent function was defined.

In any case, I'm applying the patch and pushing soon, as there is no reason not to.

[xu-cheng]

Thanks for the quick response.

[lervag]

Actually, using v:lnum inside the indent function is really quite bad. It makes the function only work as an indentexpr. The earlier definition allowed us to call the function on an arbitrary line directly. And I used this explicitly in autoload/vimtex/format.vim. Thus I'll have to revert the patch. Sorry!

I think the appropriate change here is to update, as I said, the rnoweb.vim plugin. It should not be too difficult.

[lervag]

However, you could do a workaround: Define a new wrapper function that calls VimtexIndent(v:lnum) and set this to be the indentexpr.

[xu-cheng]

How about create a separate function like below:

setlocal indentexpr=VimtexIndentExpr()
function! VimtexIndent(lnum)
...
endfunction
function! VimtexIndentExpr()
  return VimtexIndent(v:lnum)
endfunction

Therefore, backward compatible on old vim can be maintained.

[xu-cheng]

Define a new wrapper function that calls VimtexIndent(v:lnum) and set this to be the indentexpr.

I just thought about that. 👍

[lervag]

Ok, try now. This should solve your issue while not breaking format.vim.

[xu-cheng]

Yes, it solved the problem. Thanks again.

[lervag]

Great! And no problem :)