Feature Request: Auto-Copy Text for WikiLinkFollow

[VimWei]

Could an option be added to 'WikiLinkFollow' that allows for the selected text to be copied when a link is created?

This feature would simplify the process of using the text as a title on the new page, saving the steps of going back to copy and then re-entering the new page.

[lervag]

Interesting question. Could you give me some examples, just so it's totally clear? I.e., describe the specific workflow you are thinking about.

[VimWei]

Background: I have numerous meetings scheduled daily, which I manage on a wiki page titled 'RoadShow.' The meetings are listed in reverse chronological order to easily avoid scheduling conflicts when booking in advance.

Usage Scenario: At the start of each meeting, I follow these steps to create a new page for meeting notes:

1. Select the meeting list item and press Enter to creat a new wiki page. Here, I also implemented 'url_transform' to prevent the creation of illegal filenames, which could result in data loss. The functionality of wiki.vim is so powerful, I really love it!
   (ref: Data lost when the wiki name is truncated. vimwiki/vimwiki#1399)

       function! MyUrlTransform(text)
           let l:valid_filename_text = substitute(a:text, '[:*\?"<>|`：@#$]', '', 'g')
           let l:formatted_text = substitute(l:valid_filename_text, '/\|\s\+\|,\|，', '-', 'g')
           let l:cleaned_text = substitute(l:formatted_text, '\-\+', '-', 'g')
           return tolower(l:cleaned_text)
       endfunction
       let g:wiki_link_creation = {
           \ 'md': {
               \ 'url_transform': function('MyUrlTransform'),
           \ },
       \ }

2. Paste the meeting list item as the title on the new page (I wish wiki.vim could automatically copy the list item's title during the initial step, allowing me to conveniently paste it onto the new page, thereby streamlining my workflow.).

3. Insert the current time:

   nnoremap <leader>ts a<C-R>=strftime("%Y-%m-%d %A %H:%M:%S")<CR><Esc>

4. Begin composing the meeting summary.

[lervag]

Usage Scenario: …

Thanks for this, it is very close to what I want!

The functionality of wiki.vim is so powerful, I really love it!

💝

1. Select the meeting list item and press Enter to creat a new wiki page.

Can you show an example of such a "meeting list item"; before and after you've created the link?

2. Paste the meeting list item as the title on the new page (I wish wiki.vim could automatically copy the list item's title during the initial step, allowing me to conveniently paste it onto the new page, thereby streamlining my workflow.).

I think this is almost possible already with the template feature. It is described here: :help wiki-templates. For example, you might want to use something like this:

function! MeetingTemplate(context) abort
  call append(0, '# ' . a:context.name)
  call append(1, '')
  call append(2, strftime("%Y-%m-%d %A %H:%M:%S"))
endfunction

let g:wiki_templates = [
      \ { 'match_re': 'REGEX TO MATCH THE MEETING TITLES',
      \   'source_func': function('MeetingTemplate') },
      \]

See :help wiki-templates-context for what is available in the a:context dictionary.

[VimWei]

Can you show an example of such a "meeting list item"; before and after you've created the link?

before:
* 20240411 Thursday 08:50，Xinda Energy Chemical Industry and Capital Market Summit Forum

after:
* [20240411 Thursday 08:50，Xinda Energy Chemical Industry and Capital Market Summit Forum](20240411-thursday-0850-xinda-energy-chemical-industry-and-capital-market-summit-forum.md)

I use Chinese more often, and the titles appear much more concise than in English. Below is the case example in Chinese.

before：
* 20240411周四08:50，信达能源化工产业及资本市场高峰论坛

after:
* [20240411周四08:50，信达能源化工产业及资本市场高峰论坛](20240411周四0850-信达能源化工产业及资本市场高峰论坛.md)

[VimWei]

I think this is almost possible already with the template feature. It is described here: :help wiki-templates.

Wow, the wiki-templates are far more powerful than I need, which is amazing.

I had skimmed through the help documentation before but still didn't quite grasp everything. It appears I'll need to slowly uncover the treasure trove; the more often I read the documents, the more I discover.

[lervag]

Very glad to hear it! :)

[VimWei]

I've defined the following wiki_templates, and it can work as expected in the code..

    function! MeetingTemplate(context) abort
        call append(0, '# ' . a:context.name)
        call append(1, '')
        call append(2, strftime("%Y-%m-%d %A %H:%M:%S"))
    endfunction
    let g:wiki_templates = [
                \ { 'match_re': '\d\{8\}\(-\)\?' .
                \   '\(周[一二三四五六日]\|' .
                \   '\|mon\|tue\|wed\|thu\|fri\|sat\|sun' .
                \   '\|monday\|tuesday\|wednesday\|thursday\|friday\|saturday\|sunday\).*',
                \   'source_func': function('MeetingTemplate') },
                \]

However, the new page title isn't exactly what I want. The name obtained from a:context.name is the result of url_transform processing, such as 20240411-thursday-0850-xinda-energy-chemical-industry-and-capital-market-summit-forum, instead of the pre-url_transform text 20240411 Thursday 08:50, Xinda Energy Chemical Industry and Capital Market Summit Forum.

Clearly, using the text before url_transform as the page title is more user-friendly, whereas using the text after url_transform processing is more appropriate for filenames (at least it avoids using illegal characters such as ':' in filenames).

I attempted to define the following function, but unable to retrieve l:origin_line.

    function! MeetingTemplate(context) abort
        " echom 'a:context.origin is' . string(a:context.origin)
        " result: {'file': 'D:/WeirdData/wiki/roadshow.md', 'cursor': [0, 4, 3, 0, 3]}
        let l:origin_line = getline(a:context.origin.cursor[1])
        " echom 'l:origin_line: ' . l:origin_line
        " result: getline() get none，and can't use cursor[0] to get buffer
        let l:meeting_title = matchstr(l:origin_line, '\* \zs.*\ze')
        call append(0, '# ' . l:meeting_title)
        call append(1, '')
        call append(2, strftime("%Y-%m-%d %A %H:%M:%S"))
    endfunction

Therefore, I plan to achieve this by specifying the buffer. However, I am unable to obtain the correct buffer value through cursor[0]; the value of cursor[0] is always 0.

let l:bufnr = a:context.origin.cursor[0]
let l:lnum = a:context.origin.cursor[1]
let l:origin_line = getbufline(l:bufnr, l:lnum)[0]

Should I define a g:pre_transform_text=a:text within the function! MyUrlTransform(text)?

    "set default title
    let g:pre_transform_text = 'Title'
    function! MyUrlTransform(text)
        let g:pre_transform_text = a:text
        let l:valid_filename = substitute(a:text, '[:*\?"<>|`：!@#$%&*‘’'']', '', 'g')
        let l:formatted_filename = substitute(l:valid_filename, '\s\+\|[.。,，/+"“”<>()（）《》]', '-', 'g')
        let l:formatted_filename = substitute(l:formatted_filename, '-\+', '-', 'g')
        let l:cleaned_filename = substitute(l:formatted_filename, '^-\|-$', '', 'g')
        return tolower(l:cleaned_filename)
    endfunction
    function! MeetingTemplate(context) abort
        call append(0, '# ' . g:pre_transform_text)
        call append(1, '')
        call append(2, strftime("%Y-%m-%d %A %H:%M:%S"))
       "restore default title
        let g:pre_transform_text = 'Title'
    endfunction

It works fine.

• When creating a wiki link by typing directly, set g:pre_transform_text to 'Title'.
• When creating a link with the enter key, g:pre_transform_text is assigned the value of MyUrlTransform() a:text.

Is this the correct usage? Or is there a better implementation?

[lervag]

However, the new page title isn't exactly what I want. The name obtained from a:context.name is the result of url_transform processing, such as 20240411-thursday-0850-xinda-energy-chemical-industry-and-capital-market-summit-forum, instead of the pre-url_transform text 20240411 Thursday 08:50, Xinda Energy Chemical Industry and Capital Market Summit Forum.

Clearly, using the text before url_transform as the page title is more user-friendly, whereas using the text after url_transform processing is more appropriate for filenames (at least it avoids using illegal characters such as ':' in filenames).

Yes, that is right. I just pushed an updated that enriches the origin part of the context - I've added the original link dictionary. This should include the text and url parts, and I think you want the text part. Thus:

    function! MeetingTemplate(context) abort
        let title = get(a:context.origin.link, 'text', a:context.name)
        call append(0, '# ' . title)
        call append(1, '')
        call append(2, strftime("%Y-%m-%d %A %H:%M:%S"))
    endfunction

[VimWei]

After the upgrade, the code required for settings has become more streamlined and clearer.

That's fantastic, thank you!

[lervag]

Great, I'm glad to hear it!