WikiLinkAdd in visual mode

[A-dot-S-dot]

I'm still new to wiki.vim and I'm not sure whether I missed something. Is it possible to use WikiLinkAdd in visual mode so that the selected text is used as the description of the added link?

[lervag]

No, that's not possible at the moment. I'll consider this a feature request and will implement it when I get the time.

[A-dot-S-dot]

Great, thank you very much! 😃

[A-dot-S-dot]

I have tried to implement this feature for fzf myself. Maybe it will help you or someone else.

function! CustomLinkAdd(path, mode, ...) abort 
  if a:mode == 'visual'
    normal! gv"wd
    let l:text = trim(getreg('w'))
  else
    let l:text = ''
  endif

  let l:options = extend({
        \ 'position': getcurpos()[1:2],
        \ 'text': l:text,
        \}, a:0 > 0 ? a:1 : {})

  if wiki#paths#is_abs(a:path)
    let l:cwd = expand('%:p:h')
    let l:url = stridx(a:path, l:cwd) == 0
          \ ? wiki#paths#to_wiki_url(a:path, l:cwd)
          \ : '/' .. wiki#paths#to_wiki_url(a:path)
  else
    let l:creator = wiki#link#get_creator()
    let l:url = has_key(l:creator, 'url_transform')
          \ ? l:creator.url_transform(a:path)
          \ : a:path
  endif

  let l:link_string = wiki#link#template(l:url, l:options.text)

  let l:line = getline(l:options.position[0])
  if l:options.position[1] + 1 == col('$')
    call setline(l:options.position[0], l:line . l:link_string)
  else
    call setline(l:options.position[0],
          \ strpart(l:line, 0, l:options.position[1]-1)
          \ .. l:link_string
          \ .. strpart(l:line, l:options.position[1]-1))
  endif

  if l:options.position == getcurpos()[1:2]
    call cursor(
          \ l:options.position[0],
          \ l:options.position[1] + len(l:link_string)
          \)
  endif
endfunction

function! s:accept_link(lines) abort
  " a:lines is a list with one or two elements. Two if there was a match, else
  " one. The first element is the search query; the second element contains the
  " selected item.
  let l:path = len(a:lines) == 2
        \ ? split(a:lines[1], '#####')[0]
        \ : a:lines[0]
  let l:mode = split(a:lines[1], '#####')[1]

  call CustomLinkAdd(l:path, l:mode, { 'transform_relative': v:true })

  if l:mode=='insert'
    call feedkeys('a')
  endif
endfunction

function! CustomWikiLinkAdd(...) abort 
  let l:mode = a:0 > 0 ? a:1 : ''
  let l:fzf_opts = join([
        \ '-d"#####" --with-nth=-1 --print-query --prompt "WikiLinkAdd> "',
        \ g:wiki_fzf_links_opts,
        \])

  call fzf#run(fzf#wrap({
        \ 'source': map(
        \   wiki#page#get_all(),
        \   {_, x ->  x[0] . '#####' . l:mode . '#####' . x[1]}),
        \ 'sink*': funcref('s:accept_link'),
        \ 'options': l:fzf_opts
        \}))
endfunction

nmap <leader>wa :call CustomWikiLinkAdd() <CR>
imap <C-q> <cmd>call CustomWikiLinkAdd('insert') <CR>
xmap <leader>wa :call CustomWikiLinkAdd('visual') <CR>

By the way, this code also implements that when CustomWikiLinkAdd is called in insert mode, we end up in insert mode again.

[lervag]

Thanks! I've updated accordingly, and I think it works well. Please update and test.

[A-dot-S-dot]

Thank you!

[A-dot-S-dot]

The insert and normal mode works perfectly well in vim. However, in visual mode it hangs after selection of an element. Do you experience the same behaviour?

[lervag]

That's strange. On my side, it works as expected with fzf. I have a test file for this, so I did:

1. cd WIKI/test/example-select-methods
2. FZF_VERSION=test make (to install fzf for the test)
3. nvim --clean -u select-methods-fzf.vim to start wiki.vim with a test wiki and minimal config that only loads fzf for the select method.

Let me know if you find that the minimal example also works for you.

[A-dot-S-dot]

It is! I performed the test, but it also does not work in your minimal setup. Strangely the 'normal'-mode version and the 'insert'-mode version do work. I use vim 9.

[lervag]

Ah, yes; it seems it does not with Vim. It works in Neovim. I'll look into it.

[lervag]

Ok, I think it works better now, please update and test.