Wiki root per relative project directory

[ZeroDragon]

This is not an issue
First of all: Thanks for this awesome plugin.
I've been trying to replicate a default wiki per repository (project) and finally I was able to do it thanks to wiki.vim. It requires just a few conf lines in your .vimrc file

First create this little function

function! WikiRoot(local, root)
  let l:localDir = finddir(a:local, ';./')
  return !empty(l:localDir) ? l:localDir : a:root
endfunction

Then in your config set wiki_root as:

let g:wiki_root = WikiRoot('wiki', '~/myWiki')

Now whenever you enter into wiki mode (<leader>ww) It will look for a wiki directory in current relative directory and if it does not exists, it fallbacks to your home root wiki directory (myWiki in this case)

~/
  myWiki/
    index.wiki
  other/   <- open wiki here to load ~/other/wiki/index.wiki
    wiki/
      index.wiki
    more/ <- open wiki here to load ~/other/more/wiki/index.wiki
      wiki/
        index.wiki
  anotherDirectory/ <- open wiki here to load ~/myWiki/index.wiki
    nope

What does this do is look (recursively) from your working directory up untill / for a directory named as the first argument (in this case wiki) if it fails, it will fallback to the absolute path of your personal wiki directory.

Hope you like this hack/method :)

[lervag]

This is not an issue
First of all: Thanks for this awesome plugin.

Happy you like it! :)

I've been trying to replicate a default wiki per repository (project) and finally I was able to do it thanks to wiki.vim. It requires just a few conf lines in your .vimrc file ...

function! WikiRoot(local, root)
  let l:localDir = finddir(a:local, ';./')
  return !empty(l:localDir) ? l:localDir : a:root
endfunction

let g:wiki_root = WikiRoot('wiki', '~/myWiki')

...

Hope you like this hack/method :)

Nice! I'm glad to see people "hacking" at this kind of thing. I intend for things to be (reasonably) customizable. In this particular case, I see a minor drawback. Not with your approach, but with the current implementation. Your hack sets g:wiki_root to different values depending on from where you start Vim. But some people tend not to close Vim, and since g:wiki_root is defined on Vim startup, this idea would not necessarily work so well for them. Also, people (like me) may start Vim, then move to a project file/directory, and again the same issue.

So, a possible improvement of the plugin could be to allow g:wiki_root to specify a custom function to return the wiki root. Currently, the following code is used:

  " Try globally specified wiki
  if !empty(g:wiki_root)
    let l:root = fnamemodify(g:wiki_root, ':p')
    if l:root[-1:-1] ==# '/'
      let l:root = l:root[:-2]
    endif
    if !isdirectory(l:root)
      echoerr 'g:wiki_root is specified but it does not exist!'
    else
      return resolve(l:root)
    endif
  endif

Instead, one could do something like this (current pseudo code):

  " Try globally specified wiki
  if type(g:wiki_root) == type(function())
    let l:root = call(g:wiki_root)
    ...

This would allow you to instead do something like this:

function! WikiRoot()
  let l:local = 'wiki'
  let l:root = '~/myWiki'
  let l:localDir = finddir(l:local, ';./')
  return !empty(l:localDir) ? l:localDir : l:root
endfunction

let g:wiki_root = function('WikiRoot')

What do you think?

[ZeroDragon]

I didn't want to modify the plugin itself, thats why I came with this hacky solution. I tried what you suggested and ended up with this:

To have minimum changes to config, I modified the WikiRoot function to something like this:

" Wiki.vim automatic wiki on projects
function! WikiRoot(local, root)
  let context = {'local': a:local, 'root': a:root}
  function! context.getWiki()
    let l:localDir = finddir(self.local, ';./')
    return !empty(l:localDir) ? l:localDir : self.root
  endfunction
  return context
endfunction

This way the configuration will still take 2 params (local and global). And the function could be just easly copy-pasted and only configure in 1 place.

let g:wiki_root = WikiRoot('wiki', '~/myWiki')

To make it work then I had to change this inside the plugin itself

  " Try globally specified wiki
  if !empty(g:wiki_root)
    let l:root = type(g:wiki_root) == 4 ?
          \ g:wiki_root.getWiki() :
          \ g:wiki_root
    let l:root = fnamemodify(l:root, ':p')

But this far in the configuration It started to become too much of a handfull, and if I (you, we) have to push some changes to the plugin, Then I decided to make it better.

So instead of having a function inside .vimrc, and since I'm editing the plugin itself, I just created the function inside the plugn taking in consideration your comments:

  " Try locally specified wiki
  if !empty(g:wiki_local)
    let l:currentDir = expand('%:p:h')
    let l:localDir = finddir(g:wiki_local, l:currentDir . ';./')
    if !empty(l:localDir)
      let l:root = fnamemodify(l:localDir, ':p')
      if l:root[-1:-1] ==# '/'
        let l:root = l:root[:-2]
      endif
      if isdirectory(l:root)
        return resolve(l:root)
      endif
    endif
  endif

  " Try globally specified wiki
  ...

Then inside the .vimrc we just need to define like this:

let g:wiki_root = '~/myWiki'
let g:wiki_local = 'wiki'

Now it will first try to check for most close existence of wiki directory according to the current file you have in the buffer and if it all fails, it continues trying with g:wiki_root

Best part, it is all optional.
What do you think? If you agree I can send a pull request :)

[lervag]

I don't think the concept of the local wiki option g:wiki_local is "universal" enough. The point is to specify the wiki root and to allow a more dynamic/flexible setting. Thus, I still think the better solution is to allow g:wiki_root to be a function instead of a path.

But this far in the configuration It started to become too much of a handfull, and if I (you, we) have to push some changes to the plugin, Then I decided to make it better.

I think the following code is a pragmatic solution that should allow your use case while still being and feeling "general":

  if !empty(g:wiki_root)
    let l:root = exists('*' . g:wiki_root)
      \ ? call(g:wiki_root, [])
      \ : g:wiki_root
    let l:root = fnamemodify(simplify(l:root), ':p')
    if l:root[-1:-1] ==# '/'
      let l:root = l:root[:-2]
    endif
    if isdirectory(l:root)
      return resolve(l:root)
    else
      echoerr 'g:wiki_root is specified but the target path does not exist!'
    endif
  endif

The updated docs:

*g:wiki_root*
  An option to specify the wiki root path, i.e. the wiki that is opened with
  the `<leader>ww` mapping. The option value is a string that is either

    * a specific path,
    * the name of a function that returns a path.

  The latter method allows more flexible determination of the root path, e.g.
  project specific root paths. An example: >

    function! WikiRoot()
      let l:local = finddir('wiki', ';./')
      return !empty(l:local) ? l:local : '~/wiki'
    endfunction

    let g:wiki_root = 'WikiRoot'
<
  This setting would first search for a `wiki` directory in the current
  relative directory, and fallback to a global `wiki` if the local wiki is not
  found.

  Default: ''

Personally, I think this solution is good, as it still allows the simple original setting, avoids new options, and allows almost 100% flexibility of specifying the root path.

[ZeroDragon]

That looks awesome!

[lervag]

Great, and done. :)